Startseite

[HWE-News] [HWE-FAQ] [Tests] [Artikel] [Softwareecke] [RC5-Proxy] [Overclocking] [TreiberEcke] [HWE-FanShop] [Links]

Willkommen Gast. Bitte einloggen oder registrieren. Haben Sie Ihre Aktivierungs E-Mail übersehen?
22. Juli 2018, 06:39:00 Uhr

Einloggen mit Benutzername, Passwort und Sitzungslänge
Suche:     Erweiterte Suche
223496 Beiträge in 24102 Themen von 18378 Mitglieder, Neuestes Mitglied: WhatareThosee

RC5-Teamstats: Gestern: 0 WUs, . Platz,
Gesamt: 0 WUs, . Platz ( Members)

Übersicht Hilfe Suche Kalender Einloggen Registrieren
HWE-Forum.de  |  Netzwerke  |  Netzwerke allgemein (Moderatoren: TMK, tyco, gandal)  |  Thema: Lan Anschlus
0 Mitglieder und 1 Gast betrachten dieses Thema. « vorheriges nächstes »
Seiten: [1] Nach unten Thema versenden Drucken
Autor Thema: Lan Anschlus  (Gelesen 2347 mal)
Thydus
RC5[HWE]-Team
*****

Ranking: -11
Offline Offline

Geschlecht: Männlich
Beiträge: 205


Gwydion -> Thydus

« am: 19. Juli 2008, 16:04:09 Uhr »

Hi Leute,

Kann man per Tastenkomination die Lan Verbindung deaktivieren und wieder aktivieren ???

Gespeichert
tyco
Admin
******

Ranking: 713
Offline Offline

Geschlecht: Männlich
Beiträge: 20346


HWE rocks!

« Antwort #1 am: 19. Juli 2008, 17:18:33 Uhr »

Welches Betriebssystem verwendest du denn und mit welchen Rechten bist du dort angemeldet...Gast, Benutzer oder Admin  ???
Gespeichert
Bitte keine Supportanfragen per PM stellen.
Thydus
RC5[HWE]-Team
*****

Ranking: -11
Offline Offline

Geschlecht: Männlich
Beiträge: 205


Gwydion -> Thydus

« Antwort #2 am: 19. Juli 2008, 18:52:41 Uhr »

Also als Admin ist ja mein PC^^
Betriebssytem ist Windows XP Pro.

Ich hoffe das hilft
Gespeichert
tyco
Admin
******

Ranking: 713
Offline Offline

Geschlecht: Männlich
Beiträge: 20346


HWE rocks!

« Antwort #3 am: 19. Juli 2008, 20:26:18 Uhr »

Ich habe hier folgendes VBScript gefunden mit dem es bei mir funktioniert.

Const ssfCONTROLS = 3

sConnectionName = "LAN-Verbindung"

sEnableVerb = "&Aktivieren"
sDisableVerb = "&Deaktivieren"

set shellApp = createobject("shell.application")
set oControlPanel = shellApp.Namespace(ssfCONTROLS)

set oNetConnections = nothing
for each folderitem in oControlPanel.items
  if folderitem.name  = "Netzwerkverbindungen" then
    set oNetConnections = folderitem.getfolder: exit for
  end if
next

if oNetConnections is nothing then
  msgbox "Couldn't find 'Netzwerkverbindungen' folder"
  wscript.quit
end if

set oLanConnection = nothing
for each folderitem in oNetConnections.items
  if lcase(folderitem.name)  = lcase(sConnectionName) then
    set oLanConnection = folderitem: exit for
  end if
next

if oLanConnection is nothing then
  msgbox "Couldn't find '" & sConnectionName & "' item"
  wscript.quit
end if

bEnabled = true
set oEnableVerb = nothing
set oDisableVerb = nothing
s = "Verbs: " & vbcrlf
for each verb in oLanConnection.verbs
  s = s & vbcrlf & verb.name
  if verb.name = sEnableVerb then
    set oEnableVerb = verb
    bEnabled = false
  end if
  if verb.name = sDisableVerb then
    set oDisableVerb = verb
  end if
next

'debugging displays left just in case...
'
'msgbox s ': wscript.quit
'msgbox "Enabled: " & bEnabled ': wscript.quit

'not sure why, but invokeverb always seemed to work
'for enable but not disable.
'
'saving a reference to the appropriate verb object
'and calling the DoIt method always seems to work.
'
if bEnabled then
'  oLanConnection.invokeverb sDisableVerb
  oDisableVerb.DoIt
else
'  oLanConnection.invokeverb sEnableVerb
  oEnableVerb.DoIt
end if

'adjust the sleep duration below as needed...
'
'if you let the oLanConnection go out of scope
'and be destroyed too soon, the action of the verb
'may not take...
'
wscript.sleep 1000


Dieses Script habe ich mit dem Editor als lan_switch.vbs abgespeichert. Nach Aufruf des Scriptes wird die Netzwerkkarte deaktiviert bzw. aktiviert.

Wenn du das jetzt noch mit einer Tastenkombination aufrufen willst, dann musst du eine Desktopverknüpfung erstellen und in den Eigenschaften dieser Verknüpfung eine Tastenkombination zuweisen z.B. Strg+Alt+L
Gespeichert
Bitte keine Supportanfragen per PM stellen.
Thydus
RC5[HWE]-Team
*****

Ranking: -11
Offline Offline

Geschlecht: Männlich
Beiträge: 205


Gwydion -> Thydus

« Antwort #4 am: 20. Juli 2008, 12:20:25 Uhr »

Danke funktioniert^^
Gespeichert
Seiten: [1] Nach oben Thema versenden Drucken 
HWE-Forum.de  |  Netzwerke  |  Netzwerke allgemein (Moderatoren: TMK, tyco, gandal)  |  Thema: Lan Anschlus « vorheriges nächstes »
 

Impressum | SMF 2.0.15 | SMF © 2011, Simple Machines
Seite erstellt in 0.065 Sekunden mit 24 Abfragen.